039_LiquidsDistillation.mw

蒸留による液体の分離

イントロダクション

> restart;

容器には各液体が独自の沸点を持っている混合液が含まれています。混合液は液体から蒸気に変わり始める沸点まで加熱されます。また、蒸気には低い沸点も持っており、混合液の成分は高濃度で構成されています。その結果、最も高い沸点がある液体の成分が液相に残っている為蒸留が発生します。

[Inserted Image]

理論

2つから成る混合液の蒸留は以下の微分方程式によって定義されます:

> deq := [diff(M(t),t) = F(t) - V(t) - L(t),
       diff(M(t)*x(t),t) = F(t)*z(t) - V(t)*y(t) - L(t)*x(t),
       diff(M(t)*hL(t)*T(t),t) = F(t)*hF(t)*TF(t) - V(t)*hV(t)*T(t) - L(t)*hL(t)*T(t) + Q(t)];

deq := [diff(M(t), t) = F(t)-V(t)-L(t), (diff(M(t), t))*x(t)+M(t)*(diff(x(t), t)) = F(t)*z(t)-V(t)*y(t)-L(t)*x(t), (diff(M(t), t))*hL(t)*T(t)+M(t)*(diff(hL(t), t))*T(t)+M(t)*hL(t)*(diff(T(t), t)) = F(...deq := [diff(M(t), t) = F(t)-V(t)-L(t), (diff(M(t), t))*x(t)+M(t)*(diff(x(t), t)) = F(t)*z(t)-V(t)*y(t)-L(t)*x(t), (diff(M(t), t))*hL(t)*T(t)+M(t)*(diff(hL(t), t))*T(t)+M(t)*hL(t)*(diff(T(t), t)) = F(...

1つ目の微分方程式は量のバランスについて説明します。

M は容器のモル質量

F は入って来る液体の流れ

V は蒸気の流れ

L は流れ出る液体の流れ

2つ目の微分方程式は低い温度で沸騰する要素の量のバランスについて説明します。

変数 x、y、z は液体、蒸気、および入って来る液体の流れの低い温度で沸騰する要素の濃度です。
3つ目の微分方程式はエンタルピーのバランスについて説明します。

TF は入ってくる液体の流れの温度

T は容器の中の液体の温度

Q は容器内の熱の流れ

変数 Q、hL、hV、hF はエンタルピーです。それらは水 (cW) やエタノール (cE) の熱容量や、水 (rW) やエタノール (rE) の気化熱より得導き出されます。

> sub := hL(t) = x(t)*cE+(1-x(t))*cW,
      hV(t) = y(t)*rE+(1-y(t))*rW+y(t)*cE+(1-y(t))*cW,
      hF(t) = z(t)*cE+(1-z(t))*cW:

> deq2 := subs({sub}, deq);

deq2 := [diff(M(t), t) = F(t)-V(t)-L(t), (diff(M(t), t))*x(t)+M(t)*(diff(x(t), t)) = F(t)*z(t)-V(t)*y(t)-L(t)*x(t), (diff(M(t), t))*(x(t)*cE+(1-x(t))*cW)*T(t)+M(t)*(diff(x(t)*cE+(1-x(t))*cW, t))*T(t)+...deq2 := [diff(M(t), t) = F(t)-V(t)-L(t), (diff(M(t), t))*x(t)+M(t)*(diff(x(t), t)) = F(t)*z(t)-V(t)*y(t)-L(t)*x(t), (diff(M(t), t))*(x(t)*cE+(1-x(t))*cW)*T(t)+M(t)*(diff(x(t)*cE+(1-x(t))*cW, t))*T(t)+...deq2 := [diff(M(t), t) = F(t)-V(t)-L(t), (diff(M(t), t))*x(t)+M(t)*(diff(x(t), t)) = F(t)*z(t)-V(t)*y(t)-L(t)*x(t), (diff(M(t), t))*(x(t)*cE+(1-x(t))*cW)*T(t)+M(t)*(diff(x(t)*cE+(1-x(t))*cW, t))*T(t)+...

データ

パラメータの単位は cW、cE は [k*J/(mol*K)] 、気化熱 rW、rE は [W/(m*K)] 、容器の中の熱の流れ Q は [k*W] 、入ってくる液体の流れ F は [mol/s] 、モル質量 M は [mol] そして、温度は [℃] となります。

入ってくる流れと容器のトータルモル質量は不変です。

パラメータの値はいかになります。

> val := cE=2.43*0.046, cW=4.182*0.018, rE=840*0.046, rW=2256*0.018, Q(t)=10, F(t)=0.05, z(t)=0.1, TF(t)=20, M(t)=100, diff(M(t),t)=0;

val := cE = .11178, cW = 0.75276e-1, rE = 38.640, rW = 40.608, Q(t) = 10, F(t) = 0.5e-1, z(t) = .1, TF(t) = 20, M(t) = 100, diff(M(t), t) = 0

他の計算における測定データからの液相の濃度について、気相の沸点と低い温度で沸騰する要素の濃度の簡単な関数を抽出します。

> Tf:=(x)->16.50979463*exp(-14*x)-6.385934628*x+83.27831100:
K:=(x)->-.4244747056*exp(-25*x)+.4830909531*x+.4249877048:

解決方法

エンタルピーとパラメータの方程式を微分方程式に代入します。

> deq3:=subs({val},deq2);

deq3 := [0 = 0.5e-1-V(t)-L(t), 100*(diff(x(t), t)) = 0.5e-2-V(t)*y(t)-L(t)*x(t), 3.650400*(diff(x(t), t))*T(t)+100*(0.36504e-1*x(t)+0.75276e-1)*(diff(T(t), t)) = 10.07892640-V(t)*(-1.931496*y(t)+40.68...deq3 := [0 = 0.5e-1-V(t)-L(t), 100*(diff(x(t), t)) = 0.5e-2-V(t)*y(t)-L(t)*x(t), 3.650400*(diff(x(t), t))*T(t)+100*(0.36504e-1*x(t)+0.75276e-1)*(diff(T(t), t)) = 10.07892640-V(t)*(-1.931496*y(t)+40.68...

V と L を求める為に1つ目と2つ目の方程式を解きます。そして、その解と沸点と濃度の関数を3つ目の方程式に代入すると未知の変数 x からなる微分方程式がえられます。

> h1:=solve(deq3[1], {V(t)});

h1 := {V(t) = 0.5000000000e-1-1.*L(t)}

> h2:=solve(subs(h1,deq3[2]),{L(t)});

h2 := {L(t) = -1.*(20000.*(diff(x(t), t))-1.+10.*y(t))/(-200.*y(t)+200.*x(t))}

> deq4:=simplify(subs( h1, h2, y(t)=K(x(t)), T(t)=Tf(x(t)), deq3[3] ));

deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...deq4 := -1679.640467*(diff(x(t), t))*exp(-14.*x(t))-46.62243154*(diff(x(t), t))*x(t)+255.9283850*(diff(x(t), t))-843.7429604*x(t)*(diff(x(t), t))*exp(-14.*x(t)) = -.1250000000*(0.2758344948e11*x(t)*ex...

> sol:=dsolve({deq4,x(0)=0.1},{x(t)},type=numeric);

sol := proc (x_rkf45) local res, data, vars, solnproc, outpoint, ndsol, i; option `Copyright (c) 2000 by Waterloo Maple Inc. All rights reserved.`; _EnvDSNumericSaveDigits := Digits; Digits := 14; if ...

解の表示

液相の濃度を時間の変化について表示します。

> tmax:=10000:

> plots[odeplot](sol,[t,x(t)],0..tmax,
             title="Ethanol Concentration in the Liquid Phase",
             labels=["Time [s]","Conc."],
             labeldirections=[HORIZONTAL, VERTICAL]);

[Plot]

解を気相の濃度の関数に代入し、気相のエタノールの濃度をプロットします。

> plot('K(op(2,sol(t)[2]))',t=0..tmax,
             title="Ethanol Concentration in the Vapor Phase",
             labels=["Time [s]","Conc."],
             labeldirections=[HORIZONTAL, VERTICAL]);

[Plot]

解を温度の関数に代入し、気相の温度をプロットします。

> plot('Tf(op(2,sol(t)[2]))',t=0..tmax,
             title="Temperature of the Liquid Phase",
             labels=["Time [s]","Temp [°C]"],
             labeldirections=[HORIZONTAL, VERTICAL]);

[Plot]

結論

蒸留のための一般的な方程式を現在の特別なケースに適用すると、液体の中により低い温度で沸騰する要素の濃度を表す非線形微分方程式を得ます。Maple のアルゴリズムは非線形微分方程式を解く機能から、 製品の品質に重要なエタノールの濃縮に関する情報を得ることが出来ました。また、熱流や液体のようなパラメータが異なるシステムへの応用も可能です。

参考文献

Perry´s Chemical Engineers´ Handbook, Robert H. Perry and Don Green, sixth edition, McGraw Hill.