036_MagneticCircuit.mw

磁気回路

イントロダクション

> restart;

荷電粒子のたわみについて B=0.4T の均質の磁束密度が磁気回路のエアギャップの中で要求されます。

コイルの中で磁束密度を生産するのに必要な電流が計算されます。
問題の磁気回路は,2000回転のコイル、および発電機の金属 ( IV ( 3.75% Si )) で作られているコアから成ります。

コイルは中央のコアに巻きつけられています。

[Inserted Image]

磁気回路の特質は以下の通りです。

1. 中央の部分:高さ h1=4cm、幅 b1=3cm、長さ l1=14cm (エリア A1=12cm^2、磁束の有効な長さ:l1e=11.5cm )
2. 側:高さ h2=h3=2.5cm、幅 b2=b3=3cm、長さ l2=l3=5cm (エリア A2=A3=7.5cm^2、磁束の有効な長さ:l2e=l3e=8.5cm )

3. 4 と 5 の部分:高さ h4=h5=3cm、幅 b4=b5=3cm、長さ l4=l5=6.25cm (エリア A4=A5=9cm^2、磁束の有効な長さ: l4e=l5e=5cm )

4. エアギャップ:高さ h6=3cm、幅 b6=3cm、長さ l6=1cm

理論

磁気回路のパラメーターの計算の困難は、すべてのセクションの資料が有効な磁束密度および有効な磁界に依存する、異なる浸透性を持っているということです。

起磁力
theta は次で定義されます

Theta = n*Curr = Phi*(sum(Rmag(i), i = 1 .. n)) = sum(H(i)*l(i), i = 1 .. n) (式1)

ここで、
        
Theta は起磁力 [A]
        n はコイルの回転数 [-]

        Curr はコイルの電流 [A]

        
Phi は磁束 [Wb] 
        Rmagは磁気抵抗 [1/H]   

        H は磁界 (B = mu*H) [A/m]  

        B は磁束密度 [T]  

        l は磁束の有効な長さ [m]

        i は区域の数 [-]


磁束
Phi Phi = B*A で定義されます。漏出流出が無視される場合、それは磁気回路の全体にわたって一定です。

磁気回路の磁界が分かっている場合、磁束を計算することが可能です。それから電流を式1から計算します。

解決方法

磁気回路の特質は配列 'Dim' に書かれています.
エリアは第1列に置かれ、磁束の等価な長さは第2列に置かれます。

> Dim:=Array(1..5,1..2):

> Dim[1,1]:=12*10^(-4):
Dim[1,2]:=0.115:
Dim[2,1]:=7.5*10^(-4):
Dim[2,2]:=0.085:
Dim[3,1]:=7.5*10^(-4):
Dim[3,2]:=0.085:
Dim[4,1]:=9*10^(-4):
Dim[4,2]:=0.0525:
Dim[5,1]:=9*10^(-4):
Dim[5,2]:=0.0525:

> b6:=0.03:
l6:=0.01:

物理定数

真空 μ0 [H/m] 透磁率

> mu0:=4*Pi*10^(-7):

物質の正常な磁気カーブ

最初に,強磁性の物質の正常な磁化のカーブを構築しなければなりません。

技術文献では、HとBの関係が通常、「正常な磁化のカーブ」のプロットの形で与えられます。

H と B の値はリストの組み合わせとプロットから得ることが出来ます。

> HValue := [20, 32, 43, 50, 70, 100, 200, 500, 1000, 2000, 5000, 10000, 20000, 50000, 100000]:

> BValue := [0.04, 0.15, 0.3, 0.39, 0.59, 0.78, 1.07, 1.3, 1.4, 1.47, 1.6, 1.73, 1.85, 1.94, 1.95]:

入力をコントロールする為に値はキュービックスプライン補間し、スプライン関数 'BHCurve' をプロットします。

> BHCurve := H -> evalf( subs(x=H, spline(HValue,BValue,x,cubic)) ):

> with(plots):

Warning, the name changecoords has been redefined

> semilogplot(BHCurve(H),H = 20 .. 100000,axes = BOXED,title = `Curve of normal magnetization`,labels = [H, `B `]);

[Plot]

電流の計算

次に、必要な電流を計算します。
エアギャップの磁気コンダクタンス ( CondAG = 1/Rmag ) は ( 0.1 <= l/b < 1.3 ) です。

> CondAG := (b,l) -> mu0*b*(b/l + (0.36*b)/(2.4*b+l) + 0.14/(ln(1.05+l/b)) + 0.48);

CondAG := proc (b, l) options operator, arrow; mu0*b*(b/l+.36*b/(2.4*b+l)+.14/ln(1.05+l/b)+.48) end proc

コイルの電流は 式(1) から計算出来ます。

> Phi := 0.4*b6^2;

Phi := 0.36e-3

したがって、部分中の磁束密度 B[i] は次のとおりです:

> B := Array(1..5);
for i to 5 do
 B[i] := Phi/Dim[i,1];
end do;

B := Array([0, 0, 0, 0, 0])

B[1] := .3000000000

B[2] := .4800000000

B[3] := .4800000000

B[4] := .4000000000

B[5] := .4000000000

H[i] の部分は起磁力 Theta を計算するために必要です.

> H := Array(1..5);
for i to 5 do
 H[i] := fsolve(evalf(BHCurve(HH)=B[i]), HH=500);
end do;

H := Array([0, 0, 0, 0, 0])

H[1] := 42.99999999

H[2] := 58.07511381

H[3] := 58.07511381

H[4] := 50.83937757

H[5] := 50.83937757

それから起磁力を与えます

> Theta := evalf(add(H[c]*Dim[c,2], c=1..5)+Phi/CondAG(b6,l6));

Theta := 2382.004239

必要な磁気インダクタンスを生産するのに必要な電流

> Curr := Theta/2000;

Curr := 1.191002120

結論

電流と生成された磁界の関係は、電磁石(例えば磁気アクチュエーター(質量分析計など))のデザインにとって非常に重要です。
この例では、与えられた磁界を生産するのに必要な電流を計算しました。。

計算は単純ですが、磁気回路の物質に強磁性であるので、磁束密度と磁界の関係は非線形でありほとんどの場合、素材の特性のグラフしか与えあられません。Maple のスプライン関数はこの複雑さを克服することができます。

参考文献

Hayt, William H.: Engineering Electromagnetics; 5th. ed.; McGraw-Hill Book Company