027_BendingBridge.mw

ローディングブリッジのたわみ

イントロダクション

このワークシートでは、Maple を使って、その上で車両が質量 m を操作している、ローディングブリッジのたわみを決定する方法を示します。

[Inserted Image]

> restart;

ローディングブリッジ問題の記述

橋梁の長さは L で、車両の外側の車輪間の距離は l です。左端から車両中央の位置は x0 でその質量は mvです。E は弾性率で、 I はローディングブリッジの幾何学的な慣性モーメントです。パラメータの単位は以下の通りです。

長さ L, l, x0 [ m ]
質量 m, mv [ kg ]

EI [ Nm2 ]

パラメータの値は以下の通りです。

> L:=10:

> val:= l=1, x0=8, mv=1000, m=4000, EI=2*10^7:

問題の解

負荷は区分関数でモデル化されます。

> load:=piecewise(x<x0-l/2,0,x<x0+l/2,m+mv,0):

橋梁のたわみを記述する微分方程式は以下の通りです。

> deq := EI*diff(y(x),x,x,x,x) = -load;

deq := EI*(diff(y(x), `$`(x, 4))) = -(PIECEWISE([0, x < x0-1/2*l], [m+mv, x < x0+1/2*l], [0, otherwise]))

橋梁は2つの支点をもつ棒として考えることができます。端点での曲げモーメントはなく、橋梁に対する境界条件は以下の通りです。

> boundery:= y(0)=0, y(L)=0, D(D(y))(0)=0, D(D(y))(L)=0:

パラメータの値を代入し、微分方程式を解き、その解を y に代入します。:

> sol:=dsolve(subs(val,{deq,boundery}),y(x)):

> assign(sol):

> y:=unapply(y(x),x);

y := proc (x) options operator, arrow; piecewise(x < 15/2, 1/120000*x^3-383/480000*x, x < 17/2, 77/240000*x^3-135/4096+16109/960000*x-1/96000*x^4-9/2560*x^2, 17/2 <= x, -1/30000*x^3+257/12000-1057/120...y := proc (x) options operator, arrow; piecewise(x < 15/2, 1/120000*x^3-383/480000*x, x < 17/2, 77/240000*x^3-135/4096+16109/960000*x-1/96000*x^4-9/2560*x^2, 17/2 <= x, -1/30000*x^3+257/12000-1057/120...

これはローディングブリッジのたわみ曲線を記述する関数を与えます。最大のたわみを決定するために微分を計算しゼロ点を計算します。最大のたわみの位置は以下によって与えられます。

> tmp:=solve(diff(y(x),x)=0,x);

tmp := 1/6*1149^(1/2), -1/6*1149^(1/2), 10+1/6*429^(1/2)

ゼロ点を実際の数に変換します。

> map(evalf,[tmp]);

[5.649483753, -5.649483753, 13.45205253]

他のゼロ点は橋梁に対応していないので、唯一の物理的に可能な解は sqrt(1149)/6 です。橋梁の最大のたわみは以下によって与えられます。(単位:メートル)

> evalf(y((1*sqrt(1149))/6));

-0.3005211496e-2

解のグラフィカルな表示

橋梁のたわみのグラフィカルな表現

> plot(y(x),x=0..L,axes=BOXED, title="Bending of the Bridge", labels=["Distance","Displacement"], labeldirections=[HORIZONTAL, VERTICAL]);

[Plot]

>

結論

Maple を使用することで、ローディングブリッジの正確なたわみ曲線を計算することができます。最大たわみは与えられたパラメータのセットに対し計算されます。このたわみは、負荷が急になくなったときの ローディングブリッジの振動の計算 の中で使われます。

参考文献

K. Magnus and H.H. M?ller, Grunglagen der Technischen Mechanik, Teubner.