016_AnalysisTurbojet.mw

航空機のターボジェット

イントロダクション

以下の理想化されたターボジェットを考え、様々な条件下で生成する実質の推進力 (F[N] ) を求めます。

[Inserted Image]

> restart;

エンジニアリング公式の操作

Maple で複雑な問題の扱うには、はじめにできるだけ一般的な形で問題を定義し、それから必要に応じて詳細な部分を定義する方法が最も効果的です。通常は、最後のステップで数値データを代入し処理を行います。このプロセスは多くの研究者や開発者の問題解決方法に似通っています。"最後まで数値を代入しないしないことです。".

ステップ 1: 一般的式と公式

ターボジェットの実質推進力の一般式

> Fn := (mdot_a/g_c)*(Vbar_jx-Vbar_a)+(mdot_F/g_c)*(Vbar_jx)+A_j*(p_j-p_a);

Fn := mdot_a*(Vbar_jx-Vbar_a)/g_c+mdot_F*Vbar_jx/g_c+A_j*(p_j-p_a)

ここで入力部の空気流の質量速度は次のように与えられます。

> mdot_a := rho*Vbar_a*A_i;

mdot_a := rho*Vbar_a*A_i

空気流の内部質量速度は次のように与えられます。

> mdot_F := FA*mdot_a;

mdot_F := FA*rho*Vbar_a*A_i

海面での大気の空気密度は次のように表現されます。

> rho := rho_sea * (T_sea/T) * (P/P_sea);

rho := rho_sea*T_sea*P/(T*P_sea)

推進方程式における mdot_a, mdot_F, および rho に対する式を自動的に置き換えました。単に変数名をタイプするだけで、今の推進力方程式がどのようになっているかを見ることができます。表示された結果はターボジェットに対する推進力を計算するための一般的モデルです。

> Fn;

rho_sea*T_sea*P*Vbar_a*A_i*(Vbar_jx-Vbar_a)/(T*P_sea*g_c)+FA*rho_sea*T_sea*P*Vbar_a*A_i*Vbar_jx/(T*P_sea*g_c)+A_j*(p_j-p_a)

ステップ 2 :パラメータ値の指定

特定の推進値を計算するために、一部あるいはすべてのパラメータを指定することができます。 Maple はそれらの間の必要なすべての関係を保持します。

燃料と空気の比

> FA := 0.018:

海面での空気密度

> rho_sea := 1.225:

海面での温度

> T_sea := 288.15:

海抜 11000mでの空気温度

> T := 216.65:

海面での気圧 (気圧単位で

> P_sea := 1:

11000 mでの圧力

> P := 0.223:

ジェット速度

> Vbar_jx := 550:

空気速度

> Vbar_a := 222:

ジェット面積

> A_j := .4:

入力面積

> A_i := .6:

Dimensional(大きさ)に関する定数

> g_c := 1:

ジェット圧力

> p_j := 23*10^3:

11000 mでの空気圧力

> p_a := 22.6*10^3:

Maple は値を置き換えました。これらの値に基づき、実行推進力は次のようになります。

> Fn;

16512.84420

逆問題の解

Fn は数値を持つように見えますが、Maple はまだ、元々の "数式的" 関係を保持しています。この事を使って再び式をタイプする必要なく他の問題を解くことができます。例えば、与えられた推進力の値に対する、燃料と空気の比 (FA) を計算したい場合、逆問題となります。 Maple では、この問題を比較的簡単に扱えます。

FA を "unassigning"によって調べるべき変数として宣言します。すなわち元の数式的表現に戻します。

> FA := 'FA':

推進 Fn は適切に変更されています。

> Fn;

16033.72861+26617.53273*FA

この式を、必要な推進力の値 (例えば 20000) に等しく置くと、燃料対空気比について solve コマンドで解くことができます。

> solve(Fn=20000,FA);

.1490097309

問題をグラフィカルに解析

グラフィックスを利用して、問題を考察することもできます。ここで扱ってきた数式を、Maple の plot3d サーフェイスプロット関数で使用できる形に、簡単に変更することができます。例えば、実質速度について、空気速度 (Vbar_a) とジェット速度 (Vbar_jx) の効果を観測したいならば、今までの計算に対して使っていた式 Fn を、そのまま使うことができます。

最初に、 FA を元の値の 0.018 に設定します。 (もうこのパラメータは調べません)

> FA := 0.018:

速度変数 を割り当て解除 (Unassign) します (変数の状態に戻します)。

> Vbar_jx := 'Vbar_jx':

> Vbar_a := 'Vbar_a':

推進力の式 Fn は次のようになります。

> Fn;

.2179978111*Vbar_a*(Vbar_jx-Vbar_a)+0.3923960599e-2*Vbar_a*Vbar_jx+160.00

Fn は2変数の関数です。 対応する面をプロットすることができます。

> plot3d(Fn,Vbar_a = 0..300,Vbar_jx=0..600, style=PATCHCONTOUR, shading=ZHUE, axes=BOXED);

[Plot]