014_SensorInAir.mw

気流中のセンサー

イントロダクション

このワークシートでは、排ガス流の温度センサーの過渡応答を計算します。

[Inserted Image]

> restart;

問題の定義

センサーの初期温度は 20℃で、噴き出しの温度は 500℃です。センサーのアクティブな範囲は直径5mmでシリカガラスの小さい球の中央にあります。

各パラメータの単位は次になります。熱伝達率αは [W/(m^2*K)] 、熱伝導率λは [W/(m*K)] 、密度ρは [kg/(m^3)] 、比熱 c は [W*s/(kg*K)]

また、各パラメータの値は以下の通りです:

> val := R = .5e-2/2, alpha = 30, lambda = 1.36, rho = 2.2*10^3, c = .17*10^3;

val := R = 0.2500000000e-2, alpha = 30, lambda = 1.36, rho = 2200.0, c = 170.00

解決法

ビオナンバーは以下の様に定義されます:

> Bi := (alpha*R)/lambda;

Bi := alpha*R/lambda

> subs(val, Bi);

0.5514705882e-1

0.1 より少ないビオナンバーの場合、球にわずかな温度勾配があると考えられます。

これらの条件を含んだ微分方程式は以下の通りです:

> deq := diff(T(t),t)=-(alpha*A*(T(t)-Tu))/(c*rho*V);

deq := diff(T(t), t) = -alpha*A*(T(t)-Tu)/(c*rho*V)

A が球の表面積で V が体積の時、球の初期温度は T0 で排ガスの温度は Tu とします。

> sol:=dsolve({deq, T(0)=T0}, T(t));

sol := T(t) = Tu+exp(-alpha*A*t/(c*rho*V))*(T0-Tu)

センサーには 20℃という初期温度が与えられ、排ガスの噴き出し温度は 500℃が初期温度として与えられています。

ここで、微分方程式の解に球の表面積と体積や各パラメータを代入します。

> sub := A = 4*Pi*R^2, V=(4*Pi*R^3)/3;

sub := A = 4*Pi*R^2, V = 4/3*Pi*R^3

> assign(subs( sub, val, T0=20, Tu=500, sol)):

> T:=unapply(T(t),t);

T := proc (t) options operator, arrow; 500-480*exp(-0.9625668447e-1*t) end proc

解のグラフ表示

センサーの過渡応答をグラフで表示します。

> plot(T(t),t=0..60,axes=BOXED, labels=["Time [s]","Temp. [°C]"],
title="Temperature of the Sensor inserted in a Hot Air Stream" );

[Plot]

結論

センサーの為の分析モデルは、パラメータを調べることと、アプリケーションの応答時間を各範囲において最適化することを可能にします。

参考文献

Frank P. Incropera and David P. De Witt, Fundamentals of Heat and Mass Transfer, John Wiley & Sons.