012_CoolingFin.mw

長方形状の冷却ファン

イントロダクション

このワークシートでは、最大の熱量を与える為の冷却用フィンの高さを求めます。

[Inserted Image]

> restart;

問題の定義

体積 V、長さ l そして厚さ d がある長方形の冷却用フィンについて考えます。冷却は自由で外因からの伝達によりおこなわれます。熱伝達率  を alpha 、熱伝導率  を lambda とし、今回は、放射エネルギーを無視し、発熱体の表面温度が一定であると仮定します。

解決法

フィンの温度分布は以下の様に与えられます:

> deq := diff(diff(T(x),x),x)-(2*alpha*T(x))/(lambda*d)=0;

deq := (diff(T(x), `$`(x, 2)))-2*alpha*T(x)/(lambda*d) = 0

2*alpha/lambda を m^2 とし簡単化を行います。

> deq2 := algsubs((2*alpha)/lambda=m^2, deq);

deq2 := ((diff(T(x), `$`(x, 2)))*d-T(x)*m^2)/d = 0

この微分方程式はある境界条件を使用し解きます。まず、一つ目の条件にフィンの初期温度を発熱体の温度と周囲の流体の差の dT と等しいとします。次の条件に、フィンの先端では熱の損失が全くないとします。

> sol := simplify(convert(dsolve({deq2, T(0)=dT, D(T)(h)=0}, T(x)),trig),symbolic);

sol := T(x) = -dT*(-cosh(m*h/d^(1/2))*cosh(m*x/d^(1/2))+sinh(m*h/d^(1/2))*sinh(m*x/d^(1/2)))/cosh(m*h/d^(1/2))

フィンのベースを通る流れを使用し熱の流れを定義します。

> Q := -lambda*l*d * eval(subs(x=0, diff(rhs(sol),x)));

Q := lambda*l*d^(1/2)*dT*sinh(m*h/d^(1/2))*m/cosh(m*h/d^(1/2))

V = d*l*h を Q に代入し、d を削除したものを関数 h とします。

> s1 := subs({sqrt(d)=sqrt(V/l)/sqrt(h), 1/sqrt(d)=sqrt(h)/sqrt(V/l)}, Q);

s1 := lambda*l*(V/l)^(1/2)*dT*sinh(h^(3/2)*m/(V/l)^(1/2))*m/(h^(1/2)*cosh(h^(3/2)*m/(V/l)^(1/2)))

Q の最適値は最大値です。すなわち、その導関数について h はゼロです。

> s2 := simplify(diff(s1,h));

s2 := 1/2*lambda*l*dT*m*(-(V/l)^(1/2)*sinh(h^(3/2)*m/(V/l)^(1/2))*cosh(h^(3/2)*m/(V/l)^(1/2))+3*h^(3/2)*m)/(h^(3/2)*cosh(h^(3/2)*m/(V/l)^(1/2))^2)

m*h^(3/2)/sqrt(V/l) に t を代入し、方程式の根を求めます。

> s3 := simplify(algsubs(h^(3/2)*m/(V/l)^(1/2)=t, s2));

s3 := 1/2*lambda*dT*t*V*(-sinh(t)*cosh(t)+3*t)/(h^3*cosh(t)^2)

方程式の lambda 、V、h および dT を 1 とみなし、方程式から分子だけを取り出します。

> s4:=numer(subs(lambda=1, V=1, h=1, dT=1, s3));

s4 := t*(-sinh(t)*cosh(t)+3*t)

t の値が正の時の根が見つかります。

> tsoln:=fsolve(s4, t=0..infinity, avoid={t=0});

tsoln := 1.419223190

一定の体積と長さの条件の元、フィンの高さの最適値を得るために、これまでに代入したものを戻します。

> gl := simplify(subs({m=sqrt((2*alpha)/lambda), V=l*d*h}, (m*h^(3/2))/sqrt(V/l)=tsoln ), symbolic);

gl := h*2^(1/2)*alpha^(1/2)/(lambda^(1/2)*d^(1/2)) = 1.419223190

上記を h について解きます。

> solve(gl, h);

1.003542342*lambda^(1/2)*d^(1/2)/alpha^(1/2)

結論

数学モデルを使用すると、一定な体積の場合の最適な高さとフィンのパラメータを求めることができます。

参考文献

Frank P. Incropera and David P. De Witt, Fundamentals of Heat and Mass Transfer, John Wiley & Sons.