005_HollowCylinder.mw

中空円筒の電磁場

イントロダクション

強磁性体のチューブを定常電磁場から内部をシールドするために使うことができます。遮蔽定数を計算するために、チューブは、その軸が外側の均一電磁場 H0 [A/m] の方向に垂直になるように置いてあることにします。外側の半径をRo [m],そして内側の半径を   Ri [m]とします。

[Inserted Image]

> restart;

理論

外側の電磁場の影響下で強磁性体が磁化されます。
その結果、電磁場は外側の電磁場と磁力線双極子の場の重ね合わせとして計算することができます。

方程式の自由定数は境界条件により計算できます。

磁場のスカラー・ポテンシャル V [A] は H =-grad(V)によって定義されます。

均一磁場のスカラーポテンシャルは、極座標 (r [m],
phi [rad])により、(特性定数 A [A], B [A/m])で与えられます。

磁力線双極子の電磁場は
VD = C*cos(phi)/r (特定定数 C [A*m])で与えられます。

解決方法

均一磁場のスカラー・ポテンシャルと磁力線双極子のスカラー・ポテンシャルの重ね合わせは、外側、壁、内側の3つの方程式で表されます。
材質の透磁率は次の様に定義されます。

> mu := mur*mu0;

mu := mur*mu0

(mu0 : 真空での透磁率 [H/m], mur: 相対透磁率 [-])

外側

> V1 := A1 - B1*r*cos(phi) + (C1*cos(phi))/r;

V1 := A1-B1*r*cos(phi)+C1*cos(phi)/r

> V2 := A2 - B2*r*cos(phi) + (C2*cos(phi))/r;

V2 := A2-B2*r*cos(phi)+C2*cos(phi)/r

内側

> V3 := A3 - B3*r*cos(phi) + (C3*cos(phi))/r;

V3 := A3-B3*r*cos(phi)+C3*cos(phi)/r

内側ではポテンシャルは有限でなければなりません。従って C3 = 0 となります。
r = 0 である軸上では
phi = Pi/2 、ポテンシャルは V3 = V2 = V1 = V0 = A1 = A2 = A3 の値を持ちます。
ここでは V0 = 0 を選択します。 よって、内側は強度 Hiの均一電磁場になります。 そのため B3 = Hi と置きます。

> A3:=0: A2:=0: A1:=0: C3:=0: B3:=Hi:

外側の、十分離れた点での磁場は、シリンダによる磁場の影響を受けません。よって、次の式のようになります。V1 = B1*r*cos(phi)+C1*cos(phi)/r
~
-B1*r*cos(phi)
この結果 B1 = H0 となります。

> B1:=H0:

境界における条件は、ベクトルの接面成分 H とベクトルの法線方向成分 B ( B=mu*H ) が連続であることです。
円筒座標において
H = -grad(V) から以下の方程式が得られます。

> with(linalg):

Warning, the protected names norm and trace have been redefined and unprotected

> v := [r, phi, z];

v := [r, phi, z]

> h1:=grad(V1, v, coords=cylindrical);

h1 := vector([-H0*cos(phi)-C1*cos(phi)/r^2, (H0*r*sin(phi)-C1*sin(phi)/r)/r, 0])

> h2:=grad(V2, v, coords=cylindrical);

h2 := vector([-B2*cos(phi)-C2*cos(phi)/r^2, (B2*r*sin(phi)-C2*sin(phi)/r)/r, 0])

> h3:=grad(V3,v,coords=cylindrical);

h3 := vector([-Hi*cos(phi), Hi*sin(phi), 0])

r = Ri においおては、H の接平面成分 (h1, h2, h3 の'd/d(phi )'成分)は連続でなければなりません。

> eqHi:=simplify(evalf(subs(r=Ri,h2[2]))=evalf(subs(r=Ri,h3[2])));

eqHi := sin(phi)*(B2*Ri^2-1.*C2)/Ri^2 = Hi*sin(phi)

r = Ro においては、H の接平面成分は連続でなければなりません。

> eqHa:=simplify(evalf(subs(r=Ro,h1[2]))=evalf(subs(r=Ro,h2[2])));

eqHa := sin(phi)*(H0*Ro^2-1.*C1)/Ro^2 = sin(phi)*(B2*Ro^2-1.*C2)/Ro^2

r = Ri においては, Bの法線方向成分は連続でなければなりません。(h1, h2, h3 の 'd/d(r)' 成分)

> eqBi:=simplify(evalf(subs(r=Ri,mu*h2[1]))=evalf(subs(r=Ri,mu0*h3[1])));

eqBi := -1.*mur*mu0*cos(phi)*(B2*Ri^2+C2)/Ri^2 = -1.*mu0*Hi*cos(phi)

r = Ro においては、B の法線方向成分は連続でなければなりません。

> eqBa:=simplify(evalf(subs(r=Ro,mu0*h1[1]))=evalf(subs(r=Ro,mu*h2[1])));

eqBa := -1.*mu0*cos(phi)*(H0*Ro^2+C1)/Ro^2 = -1.*mur*mu0*cos(phi)*(B2*Ro^2+C2)/Ro^2

これらの方程式を C1, C2, B2, Hi に関して解くと

> sol:=simplify(solve({eqHi,eqHa,eqBi,eqBa},{C1,C2,B2,Hi}));

sol := {Hi = -4.*mur*H0*Ro^2/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2), C1 = H0*Ro^2*(Ro^2-1.*Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2)/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2...sol := {Hi = -4.*mur*H0*Ro^2/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2), C1 = H0*Ro^2*(Ro^2-1.*Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2)/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2...sol := {Hi = -4.*mur*H0*Ro^2/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2), C1 = H0*Ro^2*(Ro^2-1.*Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2)/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2...sol := {Hi = -4.*mur*H0*Ro^2/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2), C1 = H0*Ro^2*(Ro^2-1.*Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2)/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2...

> assign(sol);

よって、遮蔽率 'Screen' (= Hi/H0)は次の様に与えられます。

> Screen:=simplify(Hi/H0);

Screen := -4.*mur*Ro^2/(-2.*mur*Ro^2-1.*Ro^2-2.*mur*Ri^2+Ri^2-1.*mur^2*Ro^2+mur^2*Ri^2)

解のグラフィカルな表示

パラメータに値を割り当て、プロットを行います。強磁性体の相対透磁率はたいへん小さい値 mur = 6です。

> Ri:=1: Ro:=2: H0:=10: mur:=6:

等高線図をプロットするには、関数を直交座標で書かれなければならないので、半径 r と角度 phi を x と y で置き換えます。

> Vc1 := simplify(subs(phi=arctan(y/x),subs(r=sqrt(x^2+y^2),V1))):
Vc2 := simplify(subs(phi=arctan(y/x),subs(r=sqrt(x^2+y^2),V2))):
Vc3 := simplify(subs(phi=arctan(y/x),subs(r=sqrt(x^2+y^2),V3))):

プロットする区分分割関数を定義します。

> Pot := piecewise(x^2+y^2<Ri^2,Vc3,Ri^2<x^2+y^2 and x^2+y^2<Ro^2, Vc2, Ro^2<x^2+y^2, Vc1):

これで等ポテンシャルの線がプロットできます。 更に二つのサークルが表示して、チューブの位置を示します。

> with(plottools):

> c1 := circle([0,0], Ri, color=red):
c2 := circle([0,0], Ro, color=red):
p := plots[contourplot](Pot, x=-3..3, y=-3..3, scaling=constrained, color=blue,numpoints=4000):
plots[display](c1,c2,p);

[Plot]

この場合、遮蔽率は 約 0.56 です。従ってチューブの中の磁場は依然外側の値の半分以上であることがわかります。

> Screen;

.5614035088

結論

実際に磁場を遮蔽しなくてはいけない場面は数多くあります。ここでは、(透過率が大変小さい) チューブを静磁場に置き、遮蔽率を計算する例を使って、その実現法について解説しました。