CC THIS PROGRAM IS FOR SOLVIONG CAVITY FLOW BY PSI-W METHOD
CC                       1988.6.7   H.MIYACHI (KUBOTA COMPUTER LTD.)
CC
          PARAMETER (KD1=40,KD2=40)
      COMMON /MAIN/ PSI(KD1,KD2),W(KD1,KD2)
      COMMON /VELO/ U(KD1,KD2),V(KD1,KD2),UNITU
      COMMON /POSI/ X(KD1,KD2),Y(KD1,KD2)
      COMMON /WK/ WK(KD1),WKX(KD1,KD2)
      COMMON /DELT/ DX,DY,DXI,DYI
      COMMON /MAX/ MX,MY,ITE,TIME,DXI2,DYI2,DXIH,DYIH
	  dimension	sax(kd1)
      MX = KD1
      MY = KD2
	  MX1 = MX - 1
	  MY1 = MY - 1
      DT = 0.4D-2
      IMAX = 2000
      INTER = 200
C
C    MAKE GRID and initial conditoin
C
      WIDTH= 1.D0
      HEIGHT= 1.D0
      DX = 1.D0/FLOAT(MX1)*WIDTH
      DY = 1.D0/FLOAT(MY1)*HEIGHT
      DXI = 1.D0/DX
      DYI = 1.D0/DY
      DO 10 J=1,MY
      DO 10 I=1,MX
      X(I,J)=FLOAT(I-1)*DX
      Y(I,J)=FLOAT(J-1)*DY
c/* initial condition */
       PSI(I,J)=0.D0
        W (I,J)=0.D0
        U (I,J)=0.D0
        V (I,J)=0.D0
   10 CONTINUE
      WRITE(6,*) ' DX=',DX
      WRITE(6,*) ' DY=',DY
      UNITU = 1.D0
      RE = 100.D0
      DO 21 I=1,MX
      U(I,MY)=UNITU
   21 CONTINUE
c psi roop parameter
      ILAST = 500
      CONST1 = 0.8D0
      DS=1.D0
      ERR1 = 1.0D-5
c make pre_conpute parameter
      REI = 1.D0/RE
      WK1 = 2.D0*(DXI*DXI+DYI*DYI)
	  WK1 = DS/WK1
      DXIH = 0.5D0*DXI
      DYIH = 0.5D0*DYI
	  DXI2 = DXI * DXI
	  DYI2 = DYI * DYI
C
C
      TIME=0.D0
      DO 9999 ITE = 1,IMAX
      WRITE(6,*) 'ITE = ',ITE
      TIME = ITE*DT
C$DOIT INLINE
      CALL BDW
C
C     SOLV W EQ.
      DO 100 J=2,MY1
      DO 200 I=2,MX1
       J1=J+1
       J2=J-1
       I1=I+1
       I2=I-1
       UU=(PSI(I,J1)-PSI(I,J2))*DYIH
       VV=(PSI(I2,J)-PSI(I1,J))*DXIH
       DWDX = (W(I1,J)-W(I2,J))*DXIH
       DWDY = (W(I,J1)-W(I,J2))*DYIH
       DWDX2 = (W(I1,J)-2.*W(I,J)+W(I2,J))*DXI2
       DWDY2 = (W(I,J1)-2.*W(I,J)+W(I,J2))*DYI2
       WKX(I,J) = W(I,J)+DT*(-UU*DWDX-VV*DWDY+REI*(DWDX2+DWDY2))
  200 CONTINUE
  100 CONTINUE
      DO 110 J=2,MY1
      DO 110 I=1,MX
       W(I,J)=WKX(I,J)
C      WRITE(6,*) I,J,' W=',W(I,J)
  110 continue
C
C     SOLV PSI EQ.
C
      DO 999 II = 1,ILAST
      GOSA = 0.0D0
      DO 500 J = 2,MY1
      DO 600 I = 2,MX1
      I1=I+1
      I2=I-1
      J1=J+1
      J2=J-1
      DPDX2 = (PSI(I1,J)+PSI(I2,J))*DXI2
      DPDY2 = (PSI(I,J1)+PSI(I,J2))*DYI2
C     WRITE(6,*) PSI(I1,J),PSI(I,J),PSI(I2,J),DXI
      SA=(DPDX2+DPDY2+W(I,J))*WK1-PSI(I,J)
	  sax(i) = sa * sa
      GOSA = GOSA +  sax(i)
      WK(I) = PSI(I,J) + CONST1 * SA
  600 CONTINUE
      DO 500 I = 2,MX1
      PSI(I,J) = WK(I)
  500 CONTINUE
C     WRITE(6,*)'GOSA=', GOSA
      IF(GOSA .LT. ERR1) GOTO 888
  999 CONTINUE
  888 CONTINUE
C
      JP = MOD(ITE,INTER)
      IF(JP .EQ. 0) THEN
C$DOIT INLINE
	CALL PLOT
      ELSE
      ENDIF
C
 9999 CONTINUE
      WRITE(10)MX,MY
      WRITE(10)((X(I,J),I=1,MX),J=1,MY)
      WRITE(10)((Y(I,J),I=1,MX),J=1,MY)
C$DOIT INLINE
      CALL PLOT
      STOP
      END
